* Wealth index calculation. Ruben Hume, 11/02/2017. Ghana MHS 2017.

cd 'C:\gh71\wealth'.
include file='wealth_assets.sps'.
execute.
set tvars=both.

* Macro definitions to perform some recoding automatically.
* Note: Do not use an asterisk in front of a macro name to try to comment it out - it will run any way because of the way the macros are expanded.
* Delete the line instead or change the spelling of the macro in the comment.
* Do not use the names of macros in comments - they will also be expanded too, and likely will fail.

*{Create binary variables based on condition and give label }.
define dichotomize( !positional !enclose('(',')') / !positional !tokens(1) / !positional !tokens(1) )
compute !2=0.
if (!1) !2=1.
variable labels !2 !3.
value labels !2 0 'No' 1 'Yes'.
formats !2 (f1.0).
!enddefine.

*(Separate shared toilets from non-shared toilets).
define shared_fac( !positional !tokens(1) / !positional !tokens(1) / !positional !tokens(1) ).
compute !2 = 0.
do if (QH106=1).
+ if (!1=1) !2 = 1.
+ compute !1 = 0.
end if.
variable labels !2 !3.
value labels !2 0 'No' 1 'Yes'.
formats !2 (f1.0).
!enddefine.

*{Reset missing values to 'does not have', change 2 code to 0}.
define no2zero( !positional !tokens(1) )
if (missing(!1) | !1<>1) !1=0.
value labels !1 0 'No' 1 'Yes'.
!enddefine.

*{Construct Variables}.

* Source of drinking water.
dichotomize (QH101=11) QH101_11 "Source of drinking water: Piped into dwelling".
dichotomize (QH101=12) QH101_12 "Source of drinking water: Piped to yard/plot".
dichotomize (QH101=13) QH101_13 "Source of drinking water: Piped to neighbor".
dichotomize (QH101=14) QH101_14 "Source of drinking water: Public tap/standpipe".
dichotomize (QH101=21) QH101_21 "Source of drinking water: Tube well or borehole".
dichotomize (QH101=31) QH101_31 "Source of drinking water: Protected well".
dichotomize (QH101=32) QH101_32 "Source of drinking water: Unprotected well".
dichotomize (QH101=41) QH101_41 "Source of drinking water: Protected spring".
dichotomize (QH101=42) QH101_42 "Source of drinking water: Unprotected spring".
dichotomize (QH101=51) QH101_51 "Source of drinking water: Rainwater".
dichotomize (QH101=61) QH101_61 "Source of drinking water: Tanker truck".
dichotomize (QH101=71) QH101_71 "Source of drinking water: Cart with small tank".
dichotomize (QH101=81) QH101_81 "Source of drinking water: Surface water (river/dam/lake/pond/stream/canal/irrigation channel)".
dichotomize (QH101=91) QH101_91 "Source of drinking water: Bottled water".
dichotomize (QH101=92) QH101_92 "Source of drinking water: Sachet water".
dichotomize (QH101=96) QH101_96 "Source of drinking water: Other".


* Type of toilet facility.
dichotomize (QH105=11) QH105_11 "Type of toilet facility: Flush to piped sewer system".
dichotomize (QH105=12) QH105_12 "Type of toilet facility: Flush to manhole/septic tank".
dichotomize (QH105=13) QH105_13 "Type of toilet facility: Flush to pit latrine".
dichotomize (QH105=14) QH105_14 "Type of toilet facility: Flush to somewhere else".
dichotomize (QH105=15) QH105_15 "Type of toilet facility: Flush, don't know where".
dichotomize (QH105=21) QH105_21 "Type of toilet facility: Ventilated improved pit latrine".
dichotomize (QH105=22) QH105_22 "Type of toilet facility: Pit latrine with slab".
dichotomize (QH105=23) QH105_23 "Type of toilet facility: Pit latrine without slab/open pit".
dichotomize (QH105=31) QH105_31 "Type of toilet facility: Composting toilet".
dichotomize (QH105=41) QH105_41 "Type of toilet facility: Bucket toilet".
dichotomize (QH105=51) QH105_51 "Type of toilet facility: Hanging toilet/hanging latrine".
dichotomize (QH105=61) QH105_61 "Type of toilet facility: No facility/bush/field".
dichotomize (QH105=96) QH105_96 "Type of toilet facility: Other".

shared_fac QH105_11 QH105_11_sh "Type of toilet facility: Flush to piped sewer system - shared".
shared_fac QH105_12 QH105_12_sh "Type of toilet facility: Flush to manhole/septic tank - shared".
shared_fac QH105_13 QH105_13_sh "Type of toilet facility: Flush to pit latrine - shared".
shared_fac QH105_14 QH105_14_sh "Type of toilet facility: Flush to somewhere else - shared".
shared_fac QH105_15 QH105_15_sh "Type of toilet facility: Flush, don't know where - shared".
shared_fac QH105_21 QH105_21_sh "Type of toilet facility: Ventilated improved pit latrine - shared".
shared_fac QH105_22 QH105_22_sh "Type of toilet facility: Pit latrine with slab - shared".
shared_fac QH105_23 QH105_23_sh "Type of toilet facility: Pit latrine without slab/open pit - shared".
shared_fac QH105_31 QH105_31_sh "Type of toilet facility: Composting toilet - shared".
shared_fac QH105_41 QH105_41_sh "Type of toilet facility: Bucket toilet - shared".
shared_fac QH105_51 QH105_51_sh "Type of toilet facility: Hanging toilet/hanging latrine - shared".
shared_fac QH105_96 QH105_96_sh "Type of toilet facility: Other - shared".


* Type of cooking fuel.
dichotomize (QH108=1) QH108_1 "Type of cooking fuel: Electricity".
dichotomize (QH108=2) QH108_2 "Type of cooking fuel: Lpg".
dichotomize (QH108=3) QH108_3 "Type of cooking fuel: Natural gas".
dichotomize (QH108=4) QH108_4 "Type of cooking fuel: Biogas".
dichotomize (QH108=5) QH108_5 "Type of cooking fuel: Kerosene".
dichotomize (QH108=6) QH108_6 "Type of cooking fuel: Coal, lignite".
dichotomize (QH108=7) QH108_7 "Type of cooking fuel: Charcoal".
dichotomize (QH108=8) QH108_8 "Type of cooking fuel: Wood".
dichotomize (QH108=9) QH108_9 "Type of cooking fuel: Straw/shrubs/grass".
dichotomize (QH108=10) QH108_10 "Type of cooking fuel: Agricultural crop residue".
dichotomize (QH108=11) QH108_11 "Type of cooking fuel: Animal dung".
dichotomize (QH108=95) QH108_95 "Type of cooking fuel: No food cooked in household".
dichotomize (QH108=96) QH108_96 "Type of cooking fuel: Other".


* Milk cows.
if (missing(QH111A) | QH110 <> 1) QH111A=0.
missing values QH111A (99).
compute QH111A_1 = (QH111A >= 1 & QH111A <= 4).
compute QH111A_2 = (QH111A >= 5 & QH111A <= 9).
compute QH111A_3 = (QH111A >= 10 & QH111A <= 98).
variable labels QH111A_1 'Milk cows: 1-4' /QH111A_2 'Milk cows: 5-9' /QH111A_3 'Milk cows: 10+'.


* Other cattle.
if (missing(QH111B) | QH110 <> 1) QH111B=0.
missing values QH111B (99).
compute QH111B_1 = (QH111B >= 1 & QH111B <= 4).
compute QH111B_2 = (QH111B >= 5 & QH111B <= 9).
compute QH111B_3 = (QH111B >= 10 & QH111B <= 98).
variable labels QH111B_1 'Other cattle: 1-4' /QH111B_2 'Other cattle: 5-9' /QH111B_3 'Other cattle: 10+'.


* Horses/donkeys/mules.
if (missing(QH111C) | QH110 <> 1) QH111C=0.
missing values QH111C (99).
compute QH111C_1 = (QH111C >= 1 & QH111C <= 4).
compute QH111C_2 = (QH111C >= 5 & QH111C <= 9).
compute QH111C_3 = (QH111C >= 10 & QH111C <= 98).
variable labels QH111C_1 'Horses/donkeys/mules: 1-4' /QH111C_2 'Horses/donkeys/mules: 5-9' /QH111C_3 'Horses/donkeys/mules: 10+'.


* Goats.
if (missing(QH111D) | QH110 <> 1) QH111D=0.
missing values QH111D (99).
compute QH111D_1 = (QH111D >= 1 & QH111D <= 4).
compute QH111D_2 = (QH111D >= 5 & QH111D <= 9).
compute QH111D_3 = (QH111D >= 10 & QH111D <= 98).
variable labels QH111D_1 'Goats: 1-4' /QH111D_2 'Goats: 5-9' /QH111D_3 'Goats: 10+'.


* Sheep.
if (missing(QH111E) | QH110 <> 1) QH111E=0.
missing values QH111E (99).
compute QH111E_1 = (QH111E >= 1 & QH111E <= 4).
compute QH111E_2 = (QH111E >= 5 & QH111E <= 9).
compute QH111E_3 = (QH111E >= 10 & QH111E <= 98).
variable labels QH111E_1 'Sheep: 1-4' /QH111E_2 'Sheep: 5-9' /QH111E_3 'Sheep: 10+'.


* Chickens or other poultry.
if (missing(QH111F) | QH110 <> 1) QH111F=0.
missing values QH111F (99).
compute QH111F_1 = (QH111F >= 1 & QH111F <= 9).
compute QH111F_2 = (QH111F >= 10 & QH111F <= 29).
compute QH111F_3 = (QH111F >= 30 & QH111F <= 98).
variable labels QH111F_1 'Chickens or other poultry: 1-9' /QH111F_2 'Chickens or other poultry: 10-29' /QH111F_3 'Chickens or other poultry: 30+'.


* Pigs.
if (missing(QH111G) | QH110 <> 1) QH111G=0.
missing values QH111G (99).
compute QH111G_1 = (QH111G >= 1 & QH111G <= 4).
compute QH111G_2 = (QH111G >= 5 & QH111G <= 9).
compute QH111G_3 = (QH111G >= 10 & QH111G <= 98).
variable labels QH111G_1 'Pigs: 1-4' /QH111G_2 'Pigs: 5-9' /QH111G_3 'Pigs: 10+'.


* Rabbits.
if (missing(QH111H) | QH110 <> 1) QH111H=0.
missing values QH111H (99).
compute QH111H_1 = (QH111H >= 1 & QH111H <= 9).
compute QH111H_2 = (QH111H >= 10 & QH111H <= 29).
compute QH111H_3 = (QH111H >= 30 & QH111H <= 98).
variable labels QH111H_1 'Rabbits: 1-9' /QH111H_2 'Rabbits: 10-29' /QH111H_3 'Rabbits: 30+'.


* Grasscutter.
if (missing(QH111I) | QH110 <> 1) QH111I=0.
missing values QH111I (99).
compute QH111I_1 = (QH111I >= 1 & QH111I <= 9).
compute QH111I_2 = (QH111I >= 10 & QH111I <= 29).
compute QH111I_3 = (QH111I >= 30 & QH111I <= 98).
variable labels QH111I_1 'Grasscutter: 1-9' /QH111I_2 'Grasscutter: 10-29' /QH111I_3 'Grasscutter: 30+'.


* Area for agricultural land (number).
compute landarea = 0.
if (QH113U = 1) landarea = QH113N * 10000.              /* Hectare to sq.meter */
if (QH113U = 2) landarea = QH113N * 4046.8564224.       /* Acres to sq.meter */
if (QH113U = 3) landarea = QH113N * 674.477116.         /* Plots to sq.meter -> 1/6 acre */
if (QH113U = 4) landarea = QH113N * 25.29285264 .        /* Poles to sq.meter -> 1/160 acre */
if (QH113U = 9 and QH113N = 95.0) landarea = 950000.
if (QH113U = 9 and QH113N = 99.8) landarea = 999999.
if (missing(QH112 ) | QH112 <> 1) landarea=0.
missing values landarea (999999).
* Electricity.
no2zero QH114A.
* Radio.
no2zero QH114B.
* Television.
no2zero QH114C.
* Telephone (non-mobile).
no2zero QH114D.
* Computer.
no2zero QH114E.
* Refrigerator.
no2zero QH114F.
* Freezer.
no2zero QH114G.
* Generator.
no2zero QH114H.
* Washing machine.
no2zero QH114I.
* Camera.
no2zero QH114J.
* Video/dvd/vcd.
no2zero QH114K.
* Sewing machine.
no2zero QH114L.
* Bed.
no2zero QH114M.
* Table.
no2zero QH114N.
* Chair.
no2zero QH114O.
* Cabinet.
no2zero QH114P.
* Wrist watch.
no2zero QH115A.
* Mobile telephone.
no2zero QH115B.
* Bicycle.
no2zero QH115C.
* Motorcycle or scooter.
no2zero QH115D.
* Animal-drawn cart.
no2zero QH115E.
* Car, Bus or Truck.
no2zero QH115F.
* Boat with a motor.
no2zero QH115G.
* Boat without a motor.
no2zero QH115H.
* Bank account.
no2zero QH116.

* Main floor material.
dichotomize (QH117=11) QH117_11 "Main floor material: Natural: Earth/sand".
dichotomize (QH117=12) QH117_12 "Main floor material: Natural: Dung".
dichotomize (QH117=21) QH117_21 "Main floor material: Rudimentary: Wood planks".
dichotomize (QH117=22) QH117_22 "Main floor material: Rudimentary: Palm/bamboo".
dichotomize (QH117=31) QH117_31 "Main floor material: Finished: Parquet or polished wood".
dichotomize (QH117=32) QH117_32 "Main floor material: Finished: Vinyl or asphalt strips".
dichotomize (QH117=33) QH117_33 "Main floor material: Finished: Ceramic/marble/porcelain/tiles/terrazo".
dichotomize (QH117=34) QH117_34 "Main floor material: Finished: Cement".
dichotomize (QH117=35) QH117_35 "Main floor material: Finished: Woolen carpet/synthetic  carpet".
dichotomize (QH117=36) QH117_36 "Main floor material: Finished: Linoleum/rubber carpet".
dichotomize (QH117=96) QH117_96 "Main floor material: Other".


* Main roof material.
dichotomize (QH118=11) QH118_11 "Main roof material: Natural: Thatch/palm leaf".
dichotomize (QH118=12) QH118_12 "Main roof material: Natural: Mud/sod".
dichotomize (QH118=21) QH118_21 "Main roof material: Rudimentary: Rustic mat".
dichotomize (QH118=22) QH118_22 "Main roof material: Rudimentary: Palm/bamboo".
dichotomize (QH118=23) QH118_23 "Main roof material: Rudimentary: Wood planks".
dichotomize (QH118=24) QH118_24 "Main roof material: Rudimentary: Cardboard".
dichotomize (QH118=31) QH118_31 "Main roof material: Finished: Zinc/aluminium".
dichotomize (QH118=32) QH118_32 "Main roof material: Finished: Wood".
dichotomize (QH118=33) QH118_33 "Main roof material: Finished: Calamine/cement fiber".
dichotomize (QH118=34) QH118_34 "Main roof material: Finished: Ceramic/brick tiles".
dichotomize (QH118=35) QH118_35 "Main roof material: Finished: Cement".
dichotomize (QH118=36) QH118_36 "Main roof material: Finished: Roofing shingles".
dichotomize (QH118=37) QH118_37 "Main roof material: Finished: Asbestos/slate roofing sheets".
dichotomize (QH118=96) QH118_96 "Main roof material: Other".


* Main wall material.
dichotomize (QH119=11) QH119_11 "Main wall material: Natural: Cane/palm/trunks".
dichotomize (QH119=12) QH119_12 "Main wall material: Natural: Mud/landcrete".
dichotomize (QH119=21) QH119_21 "Main wall material: Rudimentary: Bamboo with mud".
dichotomize (QH119=22) QH119_22 "Main wall material: Rudimentary: Stone with mud".
dichotomize (QH119=23) QH119_23 "Main wall material: Rudimentary: Uncovered adobe".
dichotomize (QH119=24) QH119_24 "Main wall material: Rudimentary: Plywood".
dichotomize (QH119=25) QH119_25 "Main wall material: Rudimentary: Cardboard".
dichotomize (QH119=26) QH119_26 "Main wall material: Rudimentary: Reused wood".
dichotomize (QH119=31) QH119_31 "Main wall material: Finished: Cement".
dichotomize (QH119=32) QH119_32 "Main wall material: Finished: Stone with lime/cement".
dichotomize (QH119=33) QH119_33 "Main wall material: Finished: Bricks".
dichotomize (QH119=34) QH119_34 "Main wall material: Finished: Cement blocks".
dichotomize (QH119=35) QH119_35 "Main wall material: Finished: Covered adobe".
dichotomize (QH119=36) QH119_36 "Main wall material: Finished: Wood planks/shingles".
dichotomize (QH119=96) QH119_96 "Main wall material: Other".

*{Members per sleeping room}.
if (hhusual=0) hhusual=hhslept.
if (QH109>0) memsleep=trunc(hhusual/QH109).
if (QH109=0) memsleep=hhusual.
if (missing(QH109) or QH109>=99 or memsleep>=98) memsleep=99.
variable labels memsleep 'Number of members per sleeping room'.
value labels memsleep 0 'Less than 1 per room'.
formats memsleep (f2.0).
missing values memsleep (99).

* Compute urban and rural variables coded (1/0) for filters later.
compute urban=(QHTYPE = 1).
compute rural=(QHTYPE = 2).
variable labels urban 'Urban' / rural 'Rural'.
value labels urban 1 'Urban' / rural 1 'Rural'.
formats urban rural (f1.0).

execute.

* Check on indicator variable creation.
frequencies variables=QHTYPE to land.

* Toilet facility by shared/not shared.
crosstabs /tables=QH105 by QH106.

* Land area by units - if there are separate units - need to convert them to one unit.
*crosstabs /tables=QH113N by QH113U.

frequencies variables=
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_92 QH101_96
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_15 QH105_21 QH105_22 QH105_23 QH105_31 QH105_41 QH105_51 QH105_61 QH105_96
  QH105_11_sh QH105_12_sh QH105_13_sh QH105_14_sh QH105_15_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_41_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_2 QH108_3 QH108_4 QH108_5 QH108_6 QH108_7 QH108_8 QH108_9 QH108_10 QH108_11 QH108_95 QH108_96
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH114N QH114O QH114P QH115A QH115B QH115C QH115D QH115E QH115F
  QH115G QH115H QH116 QH117_11 QH117_12 QH117_21 QH117_22 QH117_31 QH117_32 QH117_33 QH117_34 QH117_35 QH117_36 QH117_96
  QH118_11 QH118_12 QH118_21 QH118_22 QH118_23 QH118_24 QH118_31 QH118_32 QH118_33 QH118_34 QH118_35 QH118_36 QH118_37 QH118_96
  QH119_11 QH119_12 QH119_21 QH119_22 QH119_23 QH119_24 QH119_25 QH119_26 QH119_31 QH119_32 QH119_33 QH119_34 QH119_35 QH119_36 QH119_96
  LAND memsleep
  QH111A_1 QH111A_2 QH111A_3 QH111B_1 QH111B_2 QH111B_3
  QH111C_1 QH111C_2 QH111C_3 QH111D_1 QH111D_2 QH111D_3
  QH111E_1 QH111E_2 QH111E_3 QH111F_1 QH111F_2 QH111F_3
  QH111G_1 QH111G_2 QH111G_3 QH111H_1 QH111H_2 QH111H_3
  QH111I_1 QH111I_2 QH111I_3 landarea
.

* Turn off weights before all factor analysis.
weight off.

* Name the dataset window for the HH data for use later.
dataset name assets.

save outfile='assets.sav'.

*** Test Factor Analysis.
filter off.
execute.

* excluded.
* QH101_96, QH117_96, QH118_96.
* QH105_96, QH105_11_sh, QH108_11, QH108_96, QH111I_3 .
factor /variables
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_92 
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_15 QH105_21 QH105_22 QH105_23 QH105_31 QH105_41 QH105_51 QH105_61 
  QH105_11_sh QH105_12_sh QH105_13_sh QH105_14_sh QH105_15_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_41_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_2 QH108_3 QH108_4 QH108_5 QH108_6 QH108_7 QH108_8 QH108_9 QH108_10  QH108_95 
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH114N QH114O QH114P QH115A QH115B QH115C QH115D QH115E QH115F
  QH115G QH115H QH116 QH117_11 QH117_12 QH117_21 QH117_22 QH117_31 QH117_32 QH117_33 QH117_34 QH117_35 QH117_36 
  QH118_11 QH118_12 QH118_21 QH118_22 QH118_23 QH118_24 QH118_31 QH118_32 QH118_33 QH118_34 QH118_35 QH118_36 QH118_37 
  QH119_11 QH119_12 QH119_21 QH119_22 QH119_23 QH119_24 QH119_25 QH119_26 QH119_31 QH119_32 QH119_33 QH119_34 QH119_35 QH119_36 QH119_96
  LAND memsleep
  QH111A_1 QH111A_2 QH111A_3 
  QH111B_1 QH111B_2 QH111B_3
  QH111C_1 QH111C_2 QH111C_3 
  QH111D_1 QH111D_2 QH111D_3
  QH111E_1 QH111E_2 QH111E_3 
  QH111F_1 QH111F_2 QH111F_3
  QH111G_1 QH111G_2 QH111G_3 
  QH111H_1 QH111H_2 QH111H_3
  QH111I_1 QH111I_2
 landarea
  /missing meansub
  /analysis
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_92 
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_15 QH105_21 QH105_22 QH105_23 QH105_31 QH105_41 QH105_51 QH105_61 
  QH105_11_sh QH105_12_sh QH105_13_sh QH105_14_sh QH105_15_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_41_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_2 QH108_3 QH108_4 QH108_5 QH108_6 QH108_7 QH108_8 QH108_9 QH108_10  QH108_95 
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH114N QH114O QH114P QH115A QH115B QH115C QH115D QH115E QH115F
  QH115G QH115H QH116 QH117_11 QH117_12 QH117_21 QH117_22 QH117_31 QH117_32 QH117_33 QH117_34 QH117_35 QH117_36 
  QH118_11 QH118_12 QH118_21 QH118_22 QH118_23 QH118_24 QH118_31 QH118_32 QH118_33 QH118_34 QH118_35 QH118_36 QH118_37 
  QH119_11 QH119_12 QH119_21 QH119_22 QH119_23 QH119_24 QH119_25 QH119_26 QH119_31 QH119_32 QH119_33 QH119_34 QH119_35 QH119_36 QH119_96
  LAND memsleep
  QH111A_1 QH111A_2 QH111A_3 
  QH111B_1 QH111B_2 QH111B_3
  QH111C_1 QH111C_2 QH111C_3 
  QH111D_1 QH111D_2 QH111D_3
  QH111E_1 QH111E_2 QH111E_3 
  QH111F_1 QH111F_2 QH111F_3
  QH111G_1 QH111G_2 QH111G_3 
  QH111H_1 QH111H_2 QH111H_3
  QH111I_1 QH111I_2
   landarea
  /print univariate initial extraction fscore
  /criteria factors(1) iterate(25)
  /extraction pc
  /rotation norotate
  /method=correlation.

*** Common Factor analysis ***.
** Removed area-specific variables **.
** Agricultural animal variables excluded
** Land area excluded
** Any others ?.

*** Common Factor Analysis.
filter off.
execute.

* excluded.
* QH105_96, QH108_11, QH108_96. 
factor /variables
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_92 
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_15 QH105_21 QH105_22 QH105_23 QH105_31 QH105_41 QH105_51 QH105_61
  QH105_11_sh QH105_12_sh QH105_13_sh QH105_14_sh QH105_15_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_41_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_2 QH108_3 QH108_4 QH108_5 QH108_6 QH108_7 QH108_8 QH108_9 QH108_10  QH108_95 
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH114N QH114O QH114P QH115A QH115B QH115C QH115D QH115E QH115F
  QH115G QH115H QH116 QH117_11 QH117_12 QH117_21 QH117_22 QH117_31 QH117_32 QH117_33 QH117_34 QH117_35 QH117_36 
  QH118_11 QH118_12 QH118_21 QH118_22 QH118_23 QH118_24 QH118_31 QH118_32 QH118_33 QH118_34 QH118_35 QH118_36 QH118_37 
  QH119_11 QH119_12 QH119_21 QH119_22 QH119_23 QH119_24 QH119_25 QH119_26 QH119_31 QH119_32 QH119_33 QH119_34 QH119_35 QH119_36 QH119_96
  LAND memsleep
  /missing meansub
  /analysis
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_92 
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_15 QH105_21 QH105_22 QH105_23 QH105_31 QH105_41 QH105_51 QH105_61
  QH105_11_sh QH105_12_sh QH105_13_sh QH105_14_sh QH105_15_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_41_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_2 QH108_3 QH108_4 QH108_5 QH108_6 QH108_7 QH108_8 QH108_9 QH108_10  QH108_95 
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH114N QH114O QH114P QH115A QH115B QH115C QH115D QH115E QH115F
  QH115G QH115H QH116 QH117_11 QH117_12 QH117_21 QH117_22 QH117_31 QH117_32 QH117_33 QH117_34 QH117_35 QH117_36 
  QH118_11 QH118_12 QH118_21 QH118_22 QH118_23 QH118_24 QH118_31 QH118_32 QH118_33 QH118_34 QH118_35 QH118_36 QH118_37 
  QH119_11 QH119_12 QH119_21 QH119_22 QH119_23 QH119_24 QH119_25 QH119_26 QH119_31 QH119_32 QH119_33 QH119_34 QH119_35 QH119_36 QH119_96
  LAND memsleep
  /print univariate initial extraction fscore
  /criteria factors(1) iterate(25)
  /extraction pc
  /rotation norotate
  /save reg(ALL com)
  /method=correlation.

*** Urban Factor Analysis.
filter off.
filter by urban.
execute.

* excluded.
*QH105_51 , QH105_96, QH108_11,  QH108_96, QH111I_3  .
factor /variables
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_92 
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_15 QH105_21 QH105_22 QH105_23 QH105_31 QH105_41 QH105_61 
  QH105_11_sh QH105_12_sh QH105_13_sh QH105_14_sh QH105_15_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_41_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_2 QH108_3 QH108_4 QH108_5 QH108_6 QH108_7 QH108_8 QH108_9 QH108_10  QH108_95
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH114N QH114O QH114P QH115A QH115B QH115C QH115D QH115E QH115F
  QH115G QH115H QH116 QH117_11 QH117_12 QH117_21 QH117_22 QH117_31 QH117_32 QH117_33 QH117_34 QH117_35 QH117_36 
  QH118_11 QH118_12 QH118_21 QH118_22 QH118_23 QH118_24 QH118_31 QH118_32 QH118_33 QH118_34 QH118_35 QH118_36 QH118_37 
  QH119_11 QH119_12 QH119_21 QH119_22 QH119_23 QH119_24 QH119_25 QH119_26 QH119_31 QH119_32 QH119_33 QH119_34 QH119_35 QH119_36 QH119_96
  LAND memsleep
  QH111A_1 QH111A_2 QH111A_3 
  QH111B_1 QH111B_2 QH111B_3
  QH111C_1 QH111C_2 QH111C_3 
  QH111D_1 QH111D_2 QH111D_3
  QH111E_1 QH111E_2 QH111E_3 
  QH111F_1 QH111F_2 QH111F_3
  QH111G_1 QH111G_2 QH111G_3 
  QH111H_1 QH111H_2 QH111H_3
  QH111I_1 QH111I_2 
  landarea
  /missing meansub
  /analysis
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_92
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_15 QH105_21 QH105_22 QH105_23 QH105_31 QH105_41 QH105_61 
  QH105_11_sh QH105_12_sh QH105_13_sh QH105_14_sh QH105_15_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_41_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_2 QH108_3 QH108_4 QH108_5 QH108_6 QH108_7 QH108_8 QH108_9 QH108_10  QH108_95
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH114N QH114O QH114P QH115A QH115B QH115C QH115D QH115E QH115F
  QH115G QH115H QH116 QH117_11 QH117_12 QH117_21 QH117_22 QH117_31 QH117_32 QH117_33 QH117_34 QH117_35 QH117_36 
  QH118_11 QH118_12 QH118_21 QH118_22 QH118_23 QH118_24 QH118_31 QH118_32 QH118_33 QH118_34 QH118_35 QH118_36 QH118_37 
  QH119_11 QH119_12 QH119_21 QH119_22 QH119_23 QH119_24 QH119_25 QH119_26 QH119_31 QH119_32 QH119_33 QH119_34 QH119_35 QH119_36 QH119_96
  LAND memsleep
  QH111A_1 QH111A_2 QH111A_3 
  QH111B_1 QH111B_2 QH111B_3
  QH111C_1 QH111C_2 QH111C_3 
  QH111D_1 QH111D_2 QH111D_3
  QH111E_1 QH111E_2 QH111E_3 
  QH111F_1 QH111F_2 QH111F_3
  QH111G_1 QH111G_2 QH111G_3 
  QH111H_1 QH111H_2 QH111H_3
  QH111I_1 QH111I_2 
  landarea
  /print univariate initial extraction fscore
  /criteria factors(1) iterate(25)
  /extraction pc
  /rotation norotate
  /save reg(ALL urb)
  /method=correlation.

*** Rural Factor Analysis.
filter off.
filter by rural.
execute.

* excluded.
* QH105_96, QH108_11, QH111I_3,  QH108_96 .
factor /variables
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_92 
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_15 QH105_21 QH105_22 QH105_23 QH105_31 QH105_41 QH105_51 QH105_61 
  QH105_11_sh QH105_12_sh QH105_13_sh QH105_14_sh QH105_15_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_41_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_2 QH108_3 QH108_4 QH108_5 QH108_6 QH108_7 QH108_8 QH108_9 QH108_10  QH108_95
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH114N QH114O QH114P QH115A QH115B QH115C QH115D QH115E QH115F
  QH115G QH115H QH116 QH117_11 QH117_12 QH117_21 QH117_22 QH117_31 QH117_32 QH117_33 QH117_34 QH117_35 QH117_36 
  QH118_11 QH118_12 QH118_21 QH118_22 QH118_23 QH118_24 QH118_31 QH118_32 QH118_33 QH118_34 QH118_35 QH118_36 QH118_37 
  QH119_11 QH119_12 QH119_21 QH119_22 QH119_23 QH119_24 QH119_25 QH119_26 QH119_31 QH119_32 QH119_33 QH119_34 QH119_35 QH119_36 QH119_96
  LAND memsleep
  QH111A_1 QH111A_2 QH111A_3
  QH111B_1 QH111B_2 QH111B_3
  QH111C_1 QH111C_2 QH111C_3
  QH111D_1 QH111D_2 QH111D_3
  QH111E_1 QH111E_2 QH111E_3
  QH111F_1 QH111F_2 QH111F_3
  QH111G_1 QH111G_2 QH111G_3
  QH111H_1 QH111H_2 QH111H_3
  QH111I_1 QH111I_2  
  landarea
  /missing meansub
  /analysis
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_92
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_15 QH105_21 QH105_22 QH105_23 QH105_31 QH105_41 QH105_51 QH105_61 
  QH105_11_sh QH105_12_sh QH105_13_sh QH105_14_sh QH105_15_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_41_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_2 QH108_3 QH108_4 QH108_5 QH108_6 QH108_7 QH108_8 QH108_9 QH108_10  QH108_95 
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH114N QH114O QH114P QH115A QH115B QH115C QH115D QH115E QH115F
  QH115G QH115H QH116 QH117_11 QH117_12 QH117_21 QH117_22 QH117_31 QH117_32 QH117_33 QH117_34 QH117_35 QH117_36 
  QH118_11 QH118_12 QH118_21 QH118_22 QH118_23 QH118_24 QH118_31 QH118_32 QH118_33 QH118_34 QH118_35 QH118_36 QH118_37 
  QH119_11 QH119_12 QH119_21 QH119_22 QH119_23 QH119_24 QH119_25 QH119_26 QH119_31 QH119_32 QH119_33 QH119_34 QH119_35 QH119_36 QH119_96
  LAND memsleep
  QH111A_1 QH111A_2 QH111A_3
  QH111B_1 QH111B_2 QH111B_3
  QH111C_1 QH111C_2 QH111C_3
  QH111D_1 QH111D_2 QH111D_3
  QH111E_1 QH111E_2 QH111E_3
  QH111F_1 QH111F_2 QH111F_3
  QH111G_1 QH111G_2 QH111G_3
  QH111H_1 QH111H_2 QH111H_3
  QH111I_1 QH111I_2  
  landarea
  /print univariate initial extraction fscore
  /criteria factors(1) iterate(25)
  /extraction pc
  /rotation norotate
  /save reg(ALL rur)
  /method=correlation.

* Label the created score variables.
rename variables (com1 urb1 rur1=comscore urbscore rurscore).
variable labels comscore 'Common wealth score' /urbscore 'Urban wealth score' /rurscore 'Rural wealth score'.

* Add a variable used for linking later.
filter off.
string rowtype_ (A8).
compute rowtype_ = 'EST'.

* Calculate regressions.
** Area=urban.
filter off.
filter by urban.
execute.

* Declare a dataset to be written to in the regression.
dataset declare urbancorv.
* Run regression of comscore with urbscore.
regression
  /missing listwise
  /statistics coeff outs R anova
  /criteria=pin(.05) pout(.10)
  /noorigin
  /dependent comscore
  /method=enter urbscore
  /outfile=corv(urbancorv).

* Activate file of output from regression.
dataset activate urbancorv.
* Drop all rows of output except the coefficients.
select if (rowtype_ = 'EST').
execute.
* Delete unnecessary variables before merging.
delete variables DEPVAR_ VARNAME_.
* Rename variables containing the constant and the coefficient.
rename variables CONST_=urbconst urbscore=urbcoeff.

* Re-activate the main household data.
dataset activate assets.
* merge the coefficients.
match files /file = *
  /table = urbancorv
  /by ROWTYPE_.
execute.

* Calculate regressions.
** Area=rural.
filter off.
filter by rural.
execute.

* Declare a dataset to be written to in the regression.
dataset declare ruralcorv.
* Run regression of comscore with rurscore.
regression
  /missing listwise
  /statistics coeff outs R anova
  /criteria=pin(.05) pout(.10)
  /noorigin
  /dependent comscore
  /method=enter rurscore
  /outfile=corv(ruralcorv).

* Activate file of output from regression.
dataset activate ruralcorv.
* Drop all rows of output except the coefficients.
select if (rowtype_ = 'EST').
execute.
* Delete unnecessary variables before merging.
delete variables DEPVAR_ VARNAME_.
* Rename variables containing the constant and the coefficient.
rename variables CONST_=rurconst rurscore=rurcoeff.

* Re-activate the main household data.
dataset activate assets.
* merge the coefficients.
match files /file = *
  /table = ruralcorv
  /by ROWTYPE_.
execute.

dataset close urbancorv.
dataset close ruralcorv.
dataset activate assets.
filter off.

*** Calculate combined wealth score from Urban and Rural Scores.
* Use coefficients from urban and rural regressions above.
compute combscor=0.
print formats combscor (f11.5).
write formats combscor (f11.5).
** Urban.
if (urban = 1) combscor=urbconst+urbcoeff*urbscore.
** Rural.
if (rural = 1) combscor=rurconst+rurcoeff*rurscore.
variable labels combscor 'Combined national wealth score'.
execute.

compute hhwt = QHWEIGHT/1000000.
variable labels hhwt 'HH weights'.
formats hhwt (f12.6).
weight by hhwt.

filter off.
execute.

frequencies variables=combscor comscore
  /format=notable
  /ntiles=5
  /statistics=minimum maximum stddev mean
  /histogram normal
  /order=analysis.

filter off.
filter by urban.
execute.

frequencies variables=combscor urbscore
  /format=notable
  /ntiles=5
  /statistics=minimum maximum stddev mean
  /histogram normal
  /order=analysis.

filter off.
filter by rural.
execute.

frequencies variables=combscor rurscore
  /format=notable
  /ntiles=5
  /statistics=minimum maximum stddev mean
  /histogram normal
  /order=analysis.

filter off.
execute.

*Calculate quintiles and scores for data file.
compute hhmemwt=QHWEIGHT*hhusual/1000000.
variable labels hhmemwt 'HH members weighting for index'.
formats hhmemwt (f12.6).
weight by hhmemwt.

filter off.
filter by urban.
execute.

rank variables=urbscore (A) /rank /ntiles (5) /print=yes /ties=mean.

filter off.
filter by rural.
execute.

rank variables=rurscore (A) /rank /ntiles (5) /print=yes /ties=mean.

filter off.
execute.

rank variables=combscor (A) /rank /ntiles (5) /print=yes /ties=mean.

variable labels ncombsco 'Combined wealth index' /nurbscor 'Urban wealth index' /nrurscor 'Rural wealth index'.
value labels ncombsco nurbscor nrurscor 1 'Lowest' 2 'Second' 3 'Middle' 4 'Fourth' 5 'Highest'.

*** Check on quintiles.
frequencies variables=ncombsco nurbscor nrurscor.

weight by hhwt.

ctables /table (
  QH101_11+QH101_12+QH101_13+QH101_14+QH101_21+QH101_31+QH101_32+QH101_41+QH101_42+QH101_51+QH101_61+QH101_71+QH101_81+QH101_91+QH101_92+QH101_96+
  QH105_11+QH105_12+QH105_13+QH105_14+QH105_15+QH105_21+QH105_22+QH105_23+QH105_31+QH105_41+QH105_51+QH105_61+QH105_96+
  QH105_11_sh+QH105_12_sh+QH105_13_sh+QH105_14_sh+QH105_15_sh+QH105_21_sh+QH105_22_sh+QH105_23_sh+QH105_31_sh+QH105_41_sh+QH105_51_sh+QH105_96_sh+
  QH108_1+QH108_2+QH108_3+QH108_4+QH108_5+QH108_6+QH108_7+QH108_8+QH108_9+QH108_10+QH108_11+QH108_95+QH108_96+
  QH114A+QH114B+QH114C+QH114D+QH114E+QH114F+QH114G+QH114H+QH114I+QH114J+QH114K+QH114L+QH114M+QH114N+QH114O+QH114P+QH115A+QH115B+QH115C+QH115D+QH115E+QH115F+
  QH115G+QH115H+QH116+QH117_11+QH117_12+QH117_21+QH117_22+QH117_31+QH117_32+QH117_33+QH117_34+QH117_35+QH117_36+QH117_96+
  QH118_11+QH118_12+QH118_21+QH118_22+QH118_23+QH118_24+QH118_31+QH118_32+QH118_33+QH118_34+QH118_35+QH118_36+QH118_37+QH118_96+
  QH119_11+QH119_12+QH119_21+QH119_22+QH119_23+QH119_24+QH119_25+QH119_26+QH119_31+QH119_32+QH119_33+QH119_34+QH119_35+QH119_36+QH119_96+
  LAND+memsleep+
  QH111A_1+QH111A_2+QH111A_3+QH111B_1+QH111B_2+QH111B_3+
  QH111C_1+QH111C_2+QH111C_3+QH111D_1+QH111D_2+QH111D_3+
  QH111E_1+QH111E_2+QH111E_3+QH111F_1+QH111F_2+QH111F_3+
  QH111G_1+QH111G_2+QH111G_3+QH111H_1+QH111H_2+QH111H_3+
  QH111I_1+QH111I_2+QH111I_3+landarea
  )[S][Mean F8.3] by (ncombsco+nurbscor+nrurscor)[C]
  /slabels visible=no.

* Alternative instead of ctables.
*means tables=
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_92 QH101_96
  QH105_11 QH105_12 QH105_13 QH105_14 QH105_15 QH105_21 QH105_22 QH105_23 QH105_31 QH105_41 QH105_51 QH105_61 QH105_96
  QH105_11_sh QH105_12_sh QH105_13_sh QH105_14_sh QH105_15_sh QH105_21_sh QH105_22_sh QH105_23_sh QH105_31_sh QH105_41_sh QH105_51_sh QH105_96_sh
  QH108_1 QH108_2 QH108_3 QH108_4 QH108_5 QH108_6 QH108_7 QH108_8 QH108_9 QH108_10 QH108_11 QH108_95 QH108_96
  QH114A QH114B QH114C QH114D QH114E QH114F QH114G QH114H QH114I QH114J QH114K QH114L QH114M QH114N QH114O QH114P QH115A QH115B QH115C QH115D QH115E QH115F
  QH115G QH115H QH116 QH117_11 QH117_12 QH117_21 QH117_22 QH117_31 QH117_32 QH117_33 QH117_34 QH117_35 QH117_36 QH117_96
  QH118_11 QH118_12 QH118_21 QH118_22 QH118_23 QH118_24 QH118_31 QH118_32 QH118_33 QH118_34 QH118_35 QH118_36 QH118_37 QH118_96
  QH119_11 QH119_12 QH119_21 QH119_22 QH119_23 QH119_24 QH119_25 QH119_26 QH119_31 QH119_32 QH119_33 QH119_34 QH119_35 QH119_36 QH119_96
  LAND memsleep
  QH111A_1 QH111A_2 QH111A_3 QH111B_1 QH111B_2 QH111B_3
  QH111C_1 QH111C_2 QH111C_3 QH111D_1 QH111D_2 QH111D_3
  QH111E_1 QH111E_2 QH111E_3 QH111F_1 QH111F_2 QH111F_3
  QH111G_1 QH111G_2 QH111G_3 QH111H_1 QH111H_2 QH111H_3
  QH111I_1 QH111I_2 QH111I_3 landarea
    by ncombsco nurbscor nrurscor
  /cells mean count stddev.

graph /histogram(normal)=combscor /title= 'Distribution of Households by Wealth Scores'.
frequencies variables=combscor
  /format=notable
  /ntiles=5
  /statistics=stddev minimum maximum semean mean median mode skewness seskew kurtosis sekurt
  /order=analysis.

weight off.
filter off.
write formats combscor urbscore rurscore (f11.5).

* Save final dataset of assets.
save outfile='assets.sav'.

*** Write out scores file.
write outfile='scores.dat' table /QHCLUST QHNUMBER combscor ncombsco urbscore nurbscor rurscore nrurscor.
execute.

* Produce table 2.6 weighted by de jure population to test.
weight by hhmemwt.
compute total = 0.
variable labels total 'Total'.
value labels total 0 ' '.
ctables /vlabels variables=QHTYPE QHREGION total Ncombsco display=both
  /table QHTYPE [C] + QHREGION [C] + total [C] BY Ncombsco [C][rowpct.count '%' F8.1, totals [rowpct.count '%' F8.1, count '' F8.0]]
  /categories variables=Ncombsco total=yes
  /titles title='Table 2.6 Wealth Quintiles' ''
    'Percent distribution of the de jure population by wealth quintiles, according to residence and region, Ghana MHS 2017   '
  corner='Residence/region' /slabels visible=no.